      INTEGER FUNCTION LATZON(LATUDE)
C
C**********************************************************************
C
C   NAME- LATZON
C
C   LANGUAGE- FORTRAN 77     TYPE- FUNCTION        COMPUTER- CRAY   
C
C   VERSION- 1.0    DATE- 12/08/88   PROGRAMMER- BHASKAR U. GANTI
C   VERSION- 3.0    DATE- 05/14/96   PROGRAMMER- ALEX POZDNYAK, FDC
C      FOR REHOSTING TO THE CRAY, CHANGED R*4 DECLARATION TO REAL.
C 
C   FUNCTION-*$EK10BG*
C     THIS FUNCTION ACCEPTS LATITUDE  AND DECIDES THE LATITUDE ZONE
C     IN WHICH IT FALLS AND RETURNS THE LATITUDE ZONE NUMBER. THERE
C     ARE TWELVE LATITUDE ZONES. EACH LATITUDE ZONE IS DESCRIBED AS
C     AN AREA ENCOMPASSED BY TWO LATITUDES. THESE LATITUDE ZONES ARE:
C
C     POSITIVE LATITUDES ARE NORTH AND NEGATIVE LATITUDES ARE SOUTH
C
C      LATITUDE RANGE       ZONE        LATITUDE RANGE       ZONE
C
C      90.0S TO <75.0S      1         75.0N TO <=90.0N       12
C      75.0S TO <60.0S      2         60.0N TO <75.0N        11
C      60.0S TO <45.0S      3         45.0N TO <60.0N        10
C      45.0S TO <30.0S      4         30.0N TO <45.0N         9
C      30.0S TO <15.0S      5         15.0N TO <30.0N         8
C      15.0S TO <00.0       6         00.0  TO <15.0N         7
C
C
C  CALLING SEQUENCE PARAMETERS-
C     VARIABLE         TYPE  I/O  FUNCTION
C     --------         ----  ---  --------
C     LATUDE           REAL   I   LATITUDE (DEGREES, +=NORTH, -=SOUTH)
C
      REAL  LATUDE
C
C  LOCAL PARAMETERS- NONE
C
C  SUBPROGRAMS CALLED- NONE
C
C  SUBPROGRAMS CALLING THIS- STDLEV
C******************************************************************
C
C       THE FOLLOWING TEST IS TO CHECK IF THE GIVEN LATITUDE IS
C       WITHIN THE RANGE OF (-90.0 TO +90.0). IF IT IS NOT,
C       SET LATZON VALUE TO ZERO AND RETURN
C
        IF ((LATUDE .LT. -90.0) .OR. (LATUDE .GT. 90.0)) THEN
           LATZON = 0
           RETURN
        ENDIF
C
C       COMPUTE THE LATITUDE ZONE IN WHICH LATITUDE FALLS.
C       THE FOLLOWING EQUATION ACCEPTS THE LATITUDE AND DECIDES
C       THE LATITUDE ZONE.
C
        LATZON = (((LATUDE+90.0)/15)+1)
C
C       THE ABOVE FORMULA COMPUTES LATITUDE ZONES FOR ALL
C       LATITUDES INCLUDING LATITUDE 90.0 NORTH. BUT IT PLACES
C       90.0N IN ZONE 13 WHICH IS NON-EXISTING. SO, FOLLOWING
C       TEST NEEDS TO BE DONE TO MAKE SURE 90.0 NORTH ALSO FALLS
C       IN LATITUDE ZONE 12.
C
        IF (LATUDE .EQ. 90.0) THEN
            LATZON = 12
        ENDIF
C
      RETURN
      END
