      FUNCTION ESAT(T)
C
C**********************************************************************
C
C   NAME- ESAT
C
C   LANGUAGE- FORTRAN 77  TYPE- FUNCTION        COMPUTER- CRAY
C
C   VERSION- 1.0    DATE- 12/02/88   PROGRAMMER- BHASKAR U GANTI (SMSRC)
C   VERSION- 2.0    DATE- 05/16/96   PROGRAMMER- FRANK TILLEY (SMSRC)
C     FOR REHOSTING TO CRAY, CHANGED R*4 TO REAL. DECLARED FUNCTION
C     TYPE INTERNALLY.
C
C   FUNCTION- THIS FUNCTION RETURNS THE SATURATION VAPOR PRESSURE
C             OVER WATER(MB) GIVEN THE TEMPERATURE (CELSIUS).
C             THE ALGORITHM IS DUE TO NORDQUIST, W. S., 1973:
C             "NUMERICAL APPROXIMATIONS OF SELECTED METEORLOGICAL
C             PARAMETERS FOR CLOUD PHYSICS PROBLEMS," ECOM-5475,
C             ATMOSPHERIC SCIENCES LAB, U.S. ARMY ELECTRONICS
C             COMMAND, WHITE SANDS MISSILE RANGE, NEW MEXICO.
C
C
C   CALLING SEQUENCE PARAMETERS-
C     VARIABLE          TYPE  I/O  FUNCTION
C     --------          ----  ---  --------
C     T                 REAL  I    TEMPERATURE (CELSIUS)
C
      REAL         ESAT, T
C
C   LOCAL PARAMETERS-
C     VARIABLE          TYPE  FUNCTION
C     --------          ----  --------
C     TK                REAL  TEMPERATURE IN KELVIN
C     P1                REAL  TEMP. VARIABLE
C     P2                REAL  TEMP. VARIABLE
C     C1                REAL  TEMP. VARIABLE
C
      REAL         TK,P1,P2,C1
C
C   INTRINSIC FUNCTIONS USED- ALOG10
C
C**********************************************************************
C
C
      TK = T + 273.16
      P1 = 11.344 - 0.0303998*TK
      P2 = 3.49149 - 1302.8844/TK
      C1 = 23.832241 - 5.02808*ALOG10(TK)
      ESAT=10.**(C1-1.3816E-7*10.0**P1+8.1328E-3*10.0**P2-2949.076/TK)
      RETURN
      END
